Советы по Delphi. Версия 1.4.3 от 1.1.2001 - Валентин Озеров

procedure TDBPanel.DataChange(Sender: TObject);

begin

 if FDataLink.Field 

 else Caption := FDataLink.Field.AsString;

end;

• Перекройте метод конструктора компонента Create. При реализации Create, создайте объект FDataLink и назначьте частный метод DataChange событию FDataLink OnDataChange.

{ пример }

public

 constructor Create(AOwner: TComponent); override;

.

.

implementation

.

.

constructor TMyDBPanel.Create(AOwner: TComponent);

begin

 inherited Create(AOwner);

 FDataLink := TFieldDataLink.Create;

 FDataLink.OnDataChange := DataChange;

end;

• Перекройте метод деструктора компонента Destroy. При реализации Destroy, установите OnDataChange в nil (чтобы избежать GPF), и освободите FDatalink.

{ пример }

public

.

.

destructor Destroy; override;

.

.

implementation

.

.

destructor TDBPanel.Destroy;

begin

 FDataLink.OnDataChange := nil;

 FDataLink.Free;

 inherited Destroy;

end;

• Сохраните модуль и установите компонент (смотрите документацию Users Guide и Component Writers Guide для получения дополнительной информации по сохранению модулей и установке компонентов).

• Для тестирования функциональности компонента расположите на форме компоненты TTable, TDatasource, TDBNavigator и TDBPanel. Установите TTable DatabaseName и Tablename в 'DBDemos' и 'BioLife', а свойство Active в True. Установите свойство TDatasource Dataset в Table1. Установите TDBNavigator и свойство TDBPanel DataSource в Datasource1. Имя TDBpanel DataField должно быть установлено в 'Common_Name'. Запустите приложение и, используя навигатор и перемещаясь по записям, убедитесь в том, что TDBPanel обнаруживает изменение данных и отображает значение соответствующего поля.

Полный код компонента

unit Mydbp;

interface

uses SysUtils, WinTypes, WinProcs, Messages, Classes, Graphics, Controls, Forms, Dialogs, ExtCtrls, DB, DBTables;

type TDBPanel = class(TCustomPanel)

private

 FDataLink: TFieldDataLink;

 function GetDataField: String;

 function GetDataSource: TDataSource;

 procedure SetDataField(Const Value: string);

 procedure SetDataSource(Value: TDataSource);

 procedure DataChange(Sender: TObject);

public

 constructor Create(AOwner: TComponent); override;

 destructor Destroy; override;

published

 property DataField: string read GetDataField write SetDataField;

 property DataSource: TdataSource read GetDataSource write SetDataSource;

end;

procedure Register;

implementation

procedure Register;

begin

 RegisterComponents('Samples', [TDBPanel]);

end;

function TDBPanel.GetDataField: String;

begin

 Result := FDataLink.FieldName;

end;

function TDBPanel.GetDataSource: TDataSource;

begin

 Result := FDataLink.DataSource;

end;

procedure TDBPanel.SetDataField(Const Value: string);

begin

 FDataLink.FieldName := Value;

end;

procedure TDBPanel.SetDataSource(Value: TDataSource);

begin

 FDataLink.DataSource := Value;

end;

procedure TDBPanel.DataChange(Sender: TObject);

begin

 if FDataLink.Field = nil then Caption := ''

 else Caption := FDataLink.Field.AsString;

end;

constructor TDBPanel.Create(AOwner: TComponent);

begin

 inherited Create(AOwner);

 FDataLink := TFieldDataLink.Create;

 FDataLink.OnDataChange := DataChange;

end;

destructor TDBPanel.Destroy;

begin

 FDataLink.Free;

 FDataLink.OnDataChange := nil;

 inherited Destroy;

end;

end.

Динамическое создание компонент во время работы приложения

Delphi 1

Использовать формы и компоненты Delphi очень просто. Если управлять этими объектами посредством Инспектора Объектов, то эту задачу можно отнести к числу тривиальных. Динамически создать объект также несложно. В этом документе мы обсудим некоторые вопросы, касающиеся динамического создания компонент во время работы приложения.

(вам следует помнить, что понятие "динамическое" весьма субъективно, поскольку Delphi все объекты создает динамически. Информация, предоставленная здесь — для программиста, который сам собирается создавать/менять свойства/разрушать объекты во время выполнения программы)

Все типы (формы или компоненты) могут создаваться динамически. Чтобы это сделать, необходимо объявить переменную нужного типа в секции VAR вашего кода. Это не создает экземпляр объекта, это создает указатель. Данный указатель расположен в сегменте данных (если переменная объявлена глобально) или в стеке (если переменная объявлена локально в процедуре или функции). Для того, чтобы создать экземпляр класса, вам необходимо вызвать конструктор. Это распределит память в глобальной компьютерной куче для экземпляра класса. При попытке получить доступ к компоненте прежде, чем мы распределим память, мы получим ошибку общей защиты.

Конструктор Create() является классовым методом, наследуемым от класса TObject. Create() возвращает указатель. Данный метод может потребовать (а может и нет) один или несколько параметров. В большинстве компонентов (все объекты, наследуемые от TComponent, имеют право называться компонентами), конструктор на входе требует один параметр, указывающий на "владельца" и имеющий тип TComponent.

При динамическом создании компонента в большинстве случаев владелецем становится "Self". Если вы в этот момент находитесь в одном из методов формы, "Self" в данном контексте будет ссылаться на саму форму. Если владелец является действительным объектом, освобождение этого объекта влечет за собой автоматическое освобождение "дочернего" компонента. Другим распространенным параметром является "Application". Он может использоваться в случае, когда визуальный компонент не должен быть показан программой пользователю. Тем не менее, большинство компонентов не требуют назначения владельца, так что нет ничего необычного в том, что требуемый параметр owner устанавливается в Nil. Но вы должны помнить о том, что впоследствии вы не сможете изменить владельца объекта. Если конструктору при создании был передан Nil, то после использования компонента вы должны сами освобождать его вызовом Free.

После создания оконных компонентов (т.е. тех компонентов, которые являются наследниками TWinControl), но еще перед тем, как они будут отображены, у них необходимо установить свойство Parent. Место установки свойства Parent является хорошим местом для установки других свойств экземпляра данного компонента, включая обработчики событий (например, Width, Color, OnClick).

Обработчики событий идентичны тем, которые определены в Инспекторе Объектов. Просто присвойте имени свойства компонента для события, которое вы хотите обработать, имя метода обработчика события, которое вы ожидаете. В примере 1, приведенном ниже, при нажатии на кнопку будет вызван метод с именем "myclick". Пожалуйста имейте в виду, что список входных параметров одного метода должен в точности соответствовать списку выходных параметров другого.

Пример 1:

var b1 : TButton;

begin

 .

 .

 .

 b1 := TButton.Create(Self);

 with b1 do begin

  Left := 20;

  Top := 20;

  Width := 90;

  Height := 50;

  Caption :=  'моя кнопка';

  Parent := Form1;

  OnClick :=  MyClick; { процедура, определенная где-то еще }

 end;

 .

 .

 .

end;

В следующем примере показано как можно во время выполнения программы динамически создать кнопку, щелкая по другой кнопке, размещенной на форме во время проектирования (к этому моменту она уже создана). Это уже другой путь создания кнопки. Все способы рабочие. Также имейте в виду, что кнопки, не освобождаемые в данном коде, будут освобождаться при разрушении формы.

unit Unit1;